Rules for integrands of the form  u (((e+f x))^m) (((a+b Hyper[c+d x]))^p)

1.  ∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sinh[c+d x]))dx

1:  ∫(((((e+f x))^m) ((Sinh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((z^n)/(a+b z))==((z^(n-1))/b)-((a (z^(n-1)))/(b (a+b z)))

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Sinh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/b)∫(((e+f x))^m) ((Sinh[c+d x])^(n-1))dx-(a/b)∫(((((e+f x))^m) ((Sinh[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Sinh[c+d*x]^(n-1),x] - a/b*Int[(e+f*x)^m*Sinh[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Cosh[c+d*x]^(n-1),x] - a/b*Int[(e+f*x)^m*Cosh[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

2.  ∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((((e+f x))^m) Cosh[c+d x])/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])

1:  ∫(((((e+f x))^m) Cosh[c+d x])/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0

Derivation: Algebraic expansion

Basis: If  (a^2)+(b^2)==0, then ((Cosh[z])/(a+b Sinh[z]))==(1/b)-(2/(b-a (e^z)))==-(1/b)+((2 (e^z))/(a+b (e^z)))

Basis: If  (a^2)-(b^2)==0, then ((Sinh[z])/(a+b Cosh[z]))==(1/b)-(2/(b+a (e^z)))==-(1/b)+((2 (e^z))/(a+b (e^z)))

Note: Although the first expansion is simpler, the second is used so the antiderivative will be expressed in terms of (e^(c+d x)) rather than (e^(-(c+d x))).

Rule: If  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0, then

∫(((((e+f x))^m) Cosh[c+d x])/(a+b Sinh[c+d x]))dx  ⟶  -((((e+f x))^(m+1))/(b f (m+1)))+2 ∫(((((e+f x))^m) (e^(c+d x)))/(a+b (e^(c+d x))))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]/(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  -(e+f*x)^(m+1)/(b*f*(m+1)) + 2*Int[(e+f*x)^m*E^(c+d*x)/(a+b*E^(c+d*x)),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && EqQ[a^2+b^2,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]/(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  -(e+f*x)^(m+1)/(b*f*(m+1)) + 2*Int[(e+f*x)^m*E^(c+d*x)/(a+b*E^(c+d*x)),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && EqQ[a^2-b^2,0]

2:  ∫(((((e+f x))^m) Cosh[c+d x])/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0

Derivation: Algebraic expansion

Basis: ((Cosh[z])/(a+b Sinh[z]))==(1/b)-(1/(b-(a-(Sqrt[(a^2)+(b^2)])) (e^z)))-(1/(b-(a+(Sqrt[(a^2)+(b^2)])) (e^z)))==-(1/b)+((e^z)/(a-(Sqrt[(a^2)+(b^2)])+b (e^z)))+((e^z)/(a+(Sqrt[(a^2)+(b^2)])+b (e^z)))

Basis: ((Sinh[z])/(a+b Cosh[z]))==(1/b)-(1/(b+(a-(Sqrt[(a^2)-(b^2)])) (e^z)))-(1/(b+(a+(Sqrt[(a^2)-(b^2)])) (e^z)))==-(1/b)+((e^z)/(a-(Sqrt[(a^2)-(b^2)])+b (e^z)))+((e^z)/(a+(Sqrt[(a^2)-(b^2)])+b (e^z)))

Note: Although the first expansion is simpler, the second is used so the antiderivative will be expressed in terms of (e^(c+d x)) rather than (e^(-(c+d x))).

Rule: If  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0, then

∫(((((e+f x))^m) Cosh[c+d x])/(a+b Sinh[c+d x]))dx  ⟶  -((((e+f x))^(m+1))/(b f (m+1)))+∫(((((e+f x))^m) (e^(c+d x)))/(a-(Sqrt[(a^2)+(b^2)])+b (e^(c+d x))))dx+∫(((((e+f x))^m) (e^(c+d x)))/(a+(Sqrt[(a^2)+(b^2)])+b (e^(c+d x))))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]/(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  -(e+f*x)^(m+1)/(b*f*(m+1)) + 
  Int[(e+f*x)^m*E^(c+d*x)/(a-Rt[a^2+b^2,2]+b*E^(c+d*x)),x] + 
  Int[(e+f*x)^m*E^(c+d*x)/(a+Rt[a^2+b^2,2]+b*E^(c+d*x)),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && NeQ[a^2+b^2,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]/(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  -(e+f*x)^(m+1)/(b*f*(m+1)) + 
  Int[(e+f*x)^m*E^(c+d*x)/(a-Rt[a^2-b^2,2]+b*E^(c+d*x)),x] + 
  Int[(e+f*x)^m*E^(c+d*x)/(a+Rt[a^2-b^2,2]+b*E^(c+d*x)),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && NeQ[a^2-b^2,0]

2.  ∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  n-1∈(SuperPlus[ℤ])

1:  ∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  n-1∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0

Derivation: Algebraic expansion

Basis: If  (a^2)+(b^2)==0, then (((Cosh[z])^2)/(a+b Sinh[z]))==(1/a)+((Sinh[z])/b)

Basis: If  (a^2)-(b^2)==0, then (((Sinh[z])^2)/(a+b Cosh[z]))==-(1/a)+((Cosh[z])/b)

Rule: If  n-1∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0, then

∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m) ((Cosh[c+d x])^(n-2))dx+(1/b)∫(((e+f x))^m)((Cosh[c+d x])^(n-2))Sinh[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^n_/(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Cosh[c+d*x]^(n-2),x] + 
  1/b*Int[(e+f*x)^m*Cosh[c+d*x]^(n-2)*Sinh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[n,1] && EqQ[a^2+b^2,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^n_/(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  -1/a*Int[(e+f*x)^m*Sinh[c+d*x]^(n-2),x] + 
  1/b*Int[(e+f*x)^m*Sinh[c+d*x]^(n-2)*Cosh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[n,1] && EqQ[a^2-b^2,0]

2:  ∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  n-1∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0 ∧ m∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Cosh[z])^2)/(a+b Sinh[z]))==-(a/(b^2))+((Sinh[z])/b)+(((a^2)+(b^2))/((b^2) (a+b Sinh[z])))

Basis: (((Sinh[z])^2)/(a+b Cosh[z]))==-(a/(b^2))+((Cosh[z])/b)+(((a^2)-(b^2))/((b^2) (a+b Cosh[z])))

Rule: If  n-1∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0 ∧ m∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Cosh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  
-(a/(b^2))∫(((e+f x))^m) ((Cosh[c+d x])^(n-2))dx+(1/b)∫(((e+f x))^m)((Cosh[c+d x])^(n-2))Sinh[c+d x]dx+(((a^2)+(b^2))/(b^2))∫(((((e+f x))^m) ((Cosh[c+d x])^(n-2)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^n_/(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  -a/b^2*Int[(e+f*x)^m*Cosh[c+d*x]^(n-2),x] + 
  1/b*Int[(e+f*x)^m*Cosh[c+d*x]^(n-2)*Sinh[c+d*x],x] + 
  (a^2+b^2)/b^2*Int[(e+f*x)^m*Cosh[c+d*x]^(n-2)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[n,1] && NeQ[a^2+b^2,0] && IGtQ[m,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^n_/(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  -a/b^2*Int[(e+f*x)^m*Sinh[c+d*x]^(n-2),x] + 
  1/b*Int[(e+f*x)^m*Sinh[c+d*x]^(n-2)*Cosh[c+d*x],x] + 
  (a^2-b^2)/b^2*Int[(e+f*x)^m*Sinh[c+d*x]^(n-2)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[n,1] && NeQ[a^2-b^2,0] && IGtQ[m,0]

3:  ∫(((((e+f x))^m) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Tanh[z])^p)/(a+b Sinh[z]))==((Sech[z] ((Tanh[z])^(p-1)))/b)-((a Sech[z] ((Tanh[z])^(p-1)))/(b (a+b Sinh[z])))

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/b)∫(((e+f x))^m)Sech[c+d x] ((Tanh[c+d x])^(n-1))dx-(a/b)∫(((((e+f x))^m) Sech[c+d x] ((Tanh[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Sech[c+d*x]*Tanh[c+d*x]^(n-1),x] - a/b*Int[(e+f*x)^m*Sech[c+d*x]*Tanh[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

Int[(e_.+f_.*x_)^m_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Csch[c+d*x]*Coth[c+d*x]^(n-1),x] - a/b*Int[(e+f*x)^m*Csch[c+d*x]*Coth[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

4:  ∫(((((e+f x))^m) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Coth[z])^n)/(a+b Sinh[z]))==(((Coth[z])^n)/a)-((b Cosh[z] ((Coth[z])^(n-1)))/(a (a+b Sinh[z])))

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m)((Coth[c+d x])^n)dx-(b/a)∫(((((e+f x))^m) Cosh[c+d x] ((Coth[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Coth[c+d*x]^n,x] - b/a*Int[(e+f*x)^m*Cosh[c+d*x]*Coth[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

Int[(e_.+f_.*x_)^m_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Tanh[c+d*x]^n,x] - b/a*Int[(e+f*x)^m*Sinh[c+d*x]*Tanh[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

5.  ∫(((((e+f x))^m) ((Sech[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])

1:  ∫(((((e+f x))^m) ((Sech[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0

Derivation: Algebraic expansion

Basis: If  (a^2)+(b^2)==0, then (1/(a+b Sinh[z]))==(((Sech[z])^2)/a)+((Sech[z] Tanh[z])/b)

Basis: If  (a^2)-(b^2)==0, then (1/(a+b Cosh[z]))==-(((Csch[z])^2)/a)+((Csch[z] Coth[z])/b)

Rule: If  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)==0, then

∫(((((e+f x))^m) ((Sech[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m) ((Sech[c+d x])^(n+2))dx+(1/b)∫(((e+f x))^m)((Sech[c+d x])^(n+1))Tanh[c+d x]dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Sech[c+d*x]^(n+2),x] + 
  1/b*Int[(e+f*x)^m*Sech[c+d*x]^(n+1)*Tanh[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && EqQ[a^2+b^2,0]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  -1/a*Int[(e+f*x)^m*Csch[c+d*x]^(n+2),x] + 
  1/b*Int[(e+f*x)^m*Csch[c+d*x]^(n+1)*Coth[c+d*x],x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && EqQ[a^2-b^2,0]

2:  ∫(((((e+f x))^m) ((Sech[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Sech[z])^2)/(a+b Sinh[z]))==((b^2)/(((a^2)+(b^2)) (a+b Sinh[z])))+((((Sech[z])^2) (a-b Sinh[z]))/((a^2)+(b^2)))

Basis: (((Csch[z])^2)/(a+b Cosh[z]))==((b^2)/(((a^2)-(b^2)) (a+b Cosh[z])))+((((Csch[z])^2) (a-b Cosh[z]))/((a^2)-(b^2)))

Rule: If m∈(SuperPlus[ℤ])∧ (a^2)+(b^2)≠0 ∧ n∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Sech[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  ((b^2)/((a^2)+(b^2))) ∫(((((e+f x))^m) ((Sech[c+d x])^(n-2)))/(a+b Sinh[c+d x]))dx+(1/((a^2)+(b^2))) ∫(((e+f x))^m) ((Sech[c+d x])^n) (a-b Sinh[c+d x])dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  b^2/(a^2+b^2)*Int[(e+f*x)^m*Sech[c+d*x]^(n-2)/(a+b*Sinh[c+d*x]),x] + 
  1/(a^2+b^2)*Int[(e+f*x)^m*Sech[c+d*x]^n*(a-b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && NeQ[a^2+b^2,0] && IGtQ[n,0]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  b^2/(a^2-b^2)*Int[(e+f*x)^m*Csch[c+d*x]^(n-2)/(a+b*Cosh[c+d*x]),x] + 
  1/(a^2-b^2)*Int[(e+f*x)^m*Csch[c+d*x]^n*(a-b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && NeQ[a^2-b^2,0] && IGtQ[n,0]

6:  ∫(((((e+f x))^m) ((Csch[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Csch[z])^n)/(a+b Sinh[z]))==(((Csch[z])^n)/a)-((b ((Csch[z])^(n-1)))/(a (a+b Sinh[z])))

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Csch[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m)((Csch[c+d x])^n)dx-(b/a)∫(((((e+f x))^m) ((Csch[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Csch[c+d*x]^n,x] - b/a*Int[(e+f*x)^m*Csch[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Sech[c+d*x]^n,x] - b/a*Int[(e+f*x)^m*Sech[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0]

U:  ∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sinh[c+d x]))dx

Rule:

∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  ∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  Unintegrable[(e+f*x)^m*F[c+d*x]^n/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && HyperbolicQ[F]

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  Unintegrable[(e+f*x)^m*F[c+d*x]^n/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && HyperbolicQ[F]

2.  ∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sinh[c+d x]))dx

1:  ∫(((((e+f x))^m) ((Cosh[c+d x])^p) ((Sinh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((z^n)/(a+b z))==((z^(n-1))/b)-((a (z^(n-1)))/(b (a+b z)))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Cosh[c+d x])^p) ((Sinh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/b)∫(((e+f x))^m) ((Cosh[c+d x])^p) ((Sinh[c+d x])^(n-1))dx-(a/b)∫(((((e+f x))^m) ((Cosh[c+d x])^p) ((Sinh[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^p_.*Sinh[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Cosh[c+d*x]^p*Sinh[c+d*x]^(n-1),x] - 
  a/b*Int[(e+f*x)^m*Cosh[c+d*x]^p*Sinh[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^p_.*Cosh[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Sinh[c+d*x]^p*Cosh[c+d*x]^(n-1),x] - 
  a/b*Int[(e+f*x)^m*Sinh[c+d*x]^p*Cosh[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

2:  ∫(((((e+f x))^m) ((Sinh[c+d x])^p) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Tanh[z])^p)/(a+b Sinh[z]))==(((Tanh[z])^p)/(b Sinh[z]))-((a ((Tanh[z])^p))/(b Sinh[z] (a+b Sinh[z])))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Sinh[c+d x])^p) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/b)∫(((e+f x))^m) ((Sinh[c+d x])^(p-1)) ((Tanh[c+d x])^n)dx-(a/b)∫(((((e+f x))^m) ((Sinh[c+d x])^(p-1)) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^p_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Sinh[c+d*x]^(p-1)*Tanh[c+d*x]^n,x] - 
  a/b*Int[(e+f*x)^m*Sinh[c+d*x]^(p-1)*Tanh[c+d*x]^n/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^p_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Cosh[c+d*x]^(p-1)*Coth[c+d*x]^n,x] - 
  a/b*Int[(e+f*x)^m*Cosh[c+d*x]^(p-1)*Coth[c+d*x]^n/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

3:  ∫(((((e+f x))^m) ((Sech[c+d x])^p) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Tanh[z])^p)/(a+b Sinh[z]))==((Sech[z] ((Tanh[z])^(p-1)))/b)-((a Sech[z] ((Tanh[z])^(p-1)))/(b (a+b Sinh[z])))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Sech[c+d x])^p) ((Tanh[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/b)∫(((e+f x))^m) ((Sech[c+d x])^(p+1)) ((Tanh[c+d x])^(n-1))dx-(a/b)∫(((((e+f x))^m) ((Sech[c+d x])^(p+1)) ((Tanh[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^p_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Sech[c+d*x]^(p+1)*Tanh[c+d*x]^(n-1),x] - 
  a/b*Int[(e+f*x)^m*Sech[c+d*x]^(p+1)*Tanh[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^p_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/b*Int[(e+f*x)^m*Csch[c+d*x]^(p+1)*Coth[c+d*x]^(n-1),x] - 
  a/b*Int[(e+f*x)^m*Csch[c+d*x]^(p+1)*Coth[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

4:  ∫(((((e+f x))^m) ((Cosh[c+d x])^p) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Coth[z])^n)/(a+b Sinh[z]))==(((Coth[z])^n)/a)-((b Cosh[z] ((Coth[z])^(n-1)))/(a (a+b Sinh[z])))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Cosh[c+d x])^p) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m) ((Cosh[c+d x])^p) ((Coth[c+d x])^n)dx-(b/a)∫(((((e+f x))^m) ((Cosh[c+d x])^(p+1)) ((Coth[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Cosh[c_.+d_.*x_]^p_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Cosh[c+d*x]^p*Coth[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Cosh[c+d*x]^(p+1)*Coth[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Sinh[c_.+d_.*x_]^p_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Sinh[c+d*x]^p*Tanh[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Sinh[c+d*x]^(p+1)*Tanh[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

5:  ∫(((((e+f x))^m) ((Csch[c+d x])^p) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Coth[z])^n)/(a+b Sinh[z]))==(((Coth[z])^n)/a)-((b ((Coth[z])^n))/(a Csch[z] (a+b Sinh[z])))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Csch[c+d x])^p) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m) ((Csch[c+d x])^p) ((Coth[c+d x])^n)dx-(b/a)∫(((((e+f x))^m) ((Csch[c+d x])^(p-1)) ((Coth[c+d x])^n))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^p_.*Coth[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Csch[c+d*x]^p*Coth[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Csch[c+d*x]^(p-1)*Coth[c+d*x]^n/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^p_.*Tanh[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Sech[c+d*x]^p*Tanh[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Sech[c+d*x]^(p-1)*Tanh[c+d*x]^n/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

6:  ∫(((((e+f x))^m) ((Sech[c+d x])^p) ((Csch[c+d x])^n))/(a+b Sinh[c+d x]))dx  when  (m|n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (((Csch[z])^n)/(a+b Sinh[z]))==(((Csch[z])^n)/a)-((b ((Csch[z])^(n-1)))/(a (a+b Sinh[z])))

Rule: If  (m|n|p)∈(SuperPlus[ℤ]), then

∫(((((e+f x))^m) ((Sech[c+d x])^p) ((Csch[c+d x])^n))/(a+b Sinh[c+d x]))dx  ⟶  (1/a)∫(((e+f x))^m)((Sech[c+d x])^p) ((Csch[c+d x])^n)dx-(b/a)∫(((((e+f x))^m) ((Sech[c+d x])^p) ((Csch[c+d x])^(n-1)))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*Sech[c_.+d_.*x_]^p_.*Csch[c_.+d_.*x_]^n_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Sech[c+d*x]^p*Csch[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Sech[c+d*x]^p*Csch[c+d*x]^(n-1)/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

Int[(e_.+f_.*x_)^m_.*Csch[c_.+d_.*x_]^p_.*Sech[c_.+d_.*x_]^n_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  1/a*Int[(e+f*x)^m*Csch[c+d*x]^p*Sech[c+d*x]^n,x] - 
  b/a*Int[(e+f*x)^m*Csch[c+d*x]^p*Sech[c+d*x]^(n-1)/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[p,0]

U:  ∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sinh[c+d x]))dx

Rule:

∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sinh[c+d x]))dx  ⟶  ∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_.*G_[c_.+d_.*x_]^p_./(a_+b_.*Sinh[c_.+d_.*x_]),x_Symbol] :=
  Unintegrable[(e+f*x)^m*F[c+d*x]^n*G[c+d*x]^p/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x] && HyperbolicQ[F] && HyperbolicQ[G]

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_.*G_[c_.+d_.*x_]^p_./(a_+b_.*Cosh[c_.+d_.*x_]),x_Symbol] :=
  Unintegrable[(e+f*x)^m*F[c+d*x]^n*G[c+d*x]^p/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x] && HyperbolicQ[F] && HyperbolicQ[G]

3:  ∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sech[c+d x]))dx  when  (m|n)∈ℤ

Derivation: Algebraic normalization

Basis: (1/(a+b Sech[z]))==((Cosh[z])/(b+a Cosh[z]))

Rule: If  (m|n)∈ℤ, then

∫(((((e+f x))^m) ((Hyper[c+d x])^n))/(a+b Sech[c+d x]))dx  ⟶  ∫(((((e+f x))^m) Cosh[c+d x] ((Hyper[c+d x])^n))/(b+a Cosh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_./(a_+b_.*Sech[c_.+d_.*x_]),x_Symbol] :=
  Int[(e+f*x)^m*Cosh[c+d*x]*F[c+d*x]^n/(b+a*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && HyperbolicQ[F] && IntegersQ[m,n]

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_./(a_+b_.*Csch[c_.+d_.*x_]),x_Symbol] :=
  Int[(e+f*x)^m*Sinh[c+d*x]*F[c+d*x]^n/(b+a*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && HyperbolicQ[F] && IntegersQ[m,n]

4:  ∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sech[c+d x]))dx  when  (m|n|p)∈ℤ

Derivation: Algebraic normalization

Basis: (1/(a+b Sech[z]))==((Cosh[z])/(b+a Cosh[z]))

Rule: If  (m|n|p)∈ℤ, then

∫(((((e+f x))^m) ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(a+b Sech[c+d x]))dx  ⟶  ∫(((((e+f x))^m) Cosh[c+d x] ((Hyper1[c+d x])^n) ((Hyper2[c+d x])^p))/(b+a Cosh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_.*G_[c_.+d_.*x_]^p_./(a_+b_.*Sech[c_.+d_.*x_]),x_Symbol] :=
  Int[(e+f*x)^m*Cosh[c+d*x]*F[c+d*x]^n*G[c+d*x]^p/(b+a*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && HyperbolicQ[F] && HyperbolicQ[G] && IntegersQ[m,n,p]

Int[(e_.+f_.*x_)^m_.*F_[c_.+d_.*x_]^n_.*G_[c_.+d_.*x_]^p_./(a_+b_.*Csch[c_.+d_.*x_]),x_Symbol] :=
  Int[(e+f*x)^m*Sinh[c+d*x]*F[c+d*x]^n*G[c+d*x]^p/(b+a*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && HyperbolicQ[F] && HyperbolicQ[G] && IntegersQ[m,n,p]

Rules for integrands involving hyperbolic functions

0.  ∫((Sinh[a+b x])^p)((Hyper[c+d x])^q)dx

1:  ∫((Sinh[a+b x])^p) ((Sinh[c+d x])^q)dx  when  p∈(SuperPlus[ℤ])∧ q∈ℤ

Derivation: Algebraic expansion

Basis: ((Sinh[v])^p) ((Sinh[w])^q)==(1/(2^(p+q))) (((-(e^(-v))+(e^v)))^p) (((-(e^(-w))+(e^w)))^q)

Rule: If  p∈(SuperPlus[ℤ])∧ q∈ℤ, then

∫((Sinh[a+b x])^p) ((Sinh[c+d x])^q)dx  ⟶  (1/(2^(p+q))) ∫(((-(e^(-c-d x))+(e^(c+d x))))^q) ExpandIntegrand[(((-(e^(-a-b x))+(e^(a+b x))))^p),x]dx

Program code:

Int[Sinh[a_.+b_.*x_]^p_.*Sinh[c_.+d_.*x_]^q_.,x_Symbol] :=
  1/2^(p+q)*Int[ExpandIntegrand[(-E^(-c-d*x)+E^(c+d*x))^q,(-E^(-a-b*x)+E^(a+b*x))^p,x],x] /;
FreeQ[{a,b,c,d,q},x] && IGtQ[p,0] && Not[IntegerQ[q]]

Int[Cosh[a_.+b_.*x_]^p_.*Cosh[c_.+d_.*x_]^q_.,x_Symbol] :=
  1/2^(p+q)*Int[ExpandIntegrand[(E^(-c-d*x)+E^(c+d*x))^q,(E^(-a-b*x)+E^(a+b*x))^p,x],x] /;
FreeQ[{a,b,c,d,q},x] && IGtQ[p,0] && Not[IntegerQ[q]]

2:  ∫((Sinh[a+b x])^p) ((Cosh[c+d x])^q)dx  when  p∈(SuperPlus[ℤ])∧ q∈ℤ

Derivation: Algebraic expansion

Basis: ((Sinh[v])^p) ((Cosh[w])^q)==(1/(2^(p+q))) (((-(e^(-v))+(e^v)))^p) ((((e^(-w))+(e^w)))^q)

Rule: If  p∈(SuperPlus[ℤ])∧ q∈ℤ, then

∫((Sinh[a+b x])^p) ((Cosh[c+d x])^q)dx  ⟶  (1/(2^(p+q))) ∫((((e^(-c-d x))+(e^(c+d x))))^q) ExpandIntegrand[(((-(e^(-a-b x))+(e^(a+b x))))^p),x]dx

Program code:

Int[Sinh[a_.+b_.*x_]^p_.*Cosh[c_.+d_.*x_]^q_.,x_Symbol] :=
  1/2^(p+q)*Int[ExpandIntegrand[(E^(-c-d*x)+E^(c+d*x))^q,(-E^(-a-b*x)+E^(a+b*x))^p,x],x] /;
FreeQ[{a,b,c,d,q},x] && IGtQ[p,0] && Not[IntegerQ[q]]

Int[Cosh[a_.+b_.*x_]^p_.*Sinh[c_.+d_.*x_]^q_.,x_Symbol] :=
  1/2^(p+q)*Int[ExpandIntegrand[(-E^(-c-d*x)+E^(c+d*x))^q,(E^(-a-b*x)+E^(a+b*x))^p,x],x] /;
FreeQ[{a,b,c,d,q},x] && IGtQ[p,0] && Not[IntegerQ[q]]

3:  ∫Sinh[a+b x] Tanh[c+d x]dx  when  (b^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: Sinh[v] Tanh[w]==-((e^(-v))/2)+((e^v)/2)+((e^(-v))/(1+(e^(2 w))))-((e^v)/(1+(e^(2 w))))

Basis: Cosh[v] Coth[w]==((e^(-v))/2)+((e^v)/2)-((e^(-v))/(1-(e^(2 w))))-((e^v)/(1-(e^(2 w))))

Rule: If  (b^2)-(d^2)≠0, then

∫Sinh[a+b x] Tanh[c+d x]dx  ⟶  ∫(-((e^(-a-b x))/2)+((e^(a+b x))/2)+((e^(-a-b x))/(1+(e^(2 (c+d x)))))-((e^(a+b x))/(1+(e^(2 (c+d x))))))dx

Program code:

Int[Sinh[a_.+b_.*x_]*Tanh[c_.+d_.*x_],x_Symbol] :=
  Int[-E^(-(a+b*x))/2 + E^(a+b*x)/2 + E^(-(a+b*x))/(1+E^(2*(c+d*x))) - E^(a+b*x)/(1+E^(2*(c+d*x))),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

Int[Cosh[a_.+b_.*x_]*Coth[c_.+d_.*x_],x_Symbol] :=
  Int[E^(-(a+b*x))/2 + E^(a+b*x)/2 - E^(-(a+b*x))/(1-E^(2*(c+d*x))) - E^(a+b*x)/(1-E^(2*(c+d*x))),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

4:  ∫Sinh[a+b x] Coth[c+d x]dx  when  (b^2)-(d^2)≠0

Derivation: Algebraic expansion

Basis: Sinh[v] Coth[w]==-((e^(-v))/2)+((e^v)/2)+((e^(-v))/(1-(e^(2 w))))-((e^v)/(1-(e^(2 w))))

Basis: Cosh[v] Tanh[w]==((e^(-v))/2)+((e^v)/2)-((e^(-v))/(1+(e^(2 w))))-((e^v)/(1+(e^(2 w))))

Rule: If  (b^2)-(d^2)≠0, then

∫Sinh[a+b x] Coth[c+d x]dx  ⟶  ∫(-((e^(-a-b x))/2)+((e^(a+b x))/2)+((e^(-a-b x))/(1-(e^(2 (c+d x)))))-((e^(a+b x))/(1-(e^(2 (c+d x))))))dx

Program code:

Int[Sinh[a_.+b_.*x_]*Coth[c_.+d_.*x_],x_Symbol] :=
  Int[-E^(-(a+b*x))/2 + E^(a+b*x)/2 + E^(-(a+b*x))/(1-E^(2*(c+d*x))) - E^(a+b*x)/(1-E^(2*(c+d*x))),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

Int[Cosh[a_.+b_.*x_]*Tanh[c_.+d_.*x_],x_Symbol] :=
  Int[E^(-(a+b*x))/2 + E^(a+b*x)/2 - E^(-(a+b*x))/(1+E^(2*(c+d*x))) - E^(a+b*x)/(1+E^(2*(c+d*x))),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-d^2,0]

1:  ∫((Sinh[(a/(c+d x))])^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[(a/(c+d x))]==-(1/d)Subst[((F[a x])/(x^2)),x,(1/(c+d x))] (∂_x)(1/(c+d x))

Rule: If  n∈(SuperPlus[ℤ]), then

∫((Sinh[(a/(c+d x))])^n)dx  ⟶  -(1/d) Subst[∫(((Sinh[a x])^n)/(x^2))dx,x,(1/(c+d x))]

Program code:

Int[Sinh[a_./(c_.+d_.*x_)]^n_.,x_Symbol] :=
  -1/d*Subst[Int[Sinh[a*x]^n/x^2,x],x,1/(c+d*x)] /;
FreeQ[{a,c,d},x] && IGtQ[n,0]

Int[Cosh[a_./(c_.+d_.*x_)]^n_.,x_Symbol] :=
  -1/d*Subst[Int[Cosh[a*x]^n/x^2,x],x,1/(c+d*x)] /;
FreeQ[{a,c,d},x] && IGtQ[n,0]

2.  ∫((Sinh[((a+b x)/(c+d x))])^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫((Sinh[((a+b x)/(c+d x))])^n)dx  when  n∈(SuperPlus[ℤ])∧ b c-a d≠0

Derivation: Integration by substitution

Basis: F[((a+b x)/(c+d x))]==-(1/d)Subst[((F[(b/d)-(((b c-a d) x)/d)])/(x^2)),x,(1/(c+d x))] (∂_x)(1/(c+d x))

Rule: If  n∈(SuperPlus[ℤ])∧ b c-a d≠0, then

∫((Sinh[((a+b x)/(c+d x))])^n)dx  ⟶  -(1/d) Subst[∫(((Sinh[(b/d)-(((b c-a d) x)/d)])^n)/(x^2))dx,x,(1/(c+d x))]

Program code:

Int[Sinh[e_.*(a_.+b_.*x_)/(c_.+d_.*x_)]^n_.,x_Symbol] :=
  -1/d*Subst[Int[Sinh[b*e/d-e*(b*c-a*d)*x/d]^n/x^2,x],x,1/(c+d*x)] /;
FreeQ[{a,b,c,d},x] && IGtQ[n,0] && NeQ[b*c-a*d,0]

Int[Cosh[e_.*(a_.+b_.*x_)/(c_.+d_.*x_)]^n_.,x_Symbol] :=
  -1/d*Subst[Int[Cosh[b*e/d-e*(b*c-a*d)*x/d]^n/x^2,x],x,1/(c+d*x)] /;
FreeQ[{a,b,c,d},x] && IGtQ[n,0] && NeQ[b*c-a*d,0]

2:  ∫((Sinh[u])^n)dx  when  n∈(SuperPlus[ℤ])∧ u==((a+b x)/(c+d x))

Derivation: Algebraic normalization

Rule: If  n∈(SuperPlus[ℤ])∧ u==((a+b x)/(c+d x)), then

∫((Sinh[u])^n)dx  ⟶  ∫((Sinh[((a+b x)/(c+d x))])^n)dx

Program code:

Int[Sinh[u_]^n_.,x_Symbol] :=
  With[{lst=QuotientOfLinearsParts[u,x]},
  Int[Sinh[(lst[[1]]+lst[[2]]*x)/(lst[[3]]+lst[[4]]*x)]^n,x]] /;
IGtQ[n,0] && QuotientOfLinearsQ[u,x]

Int[Cosh[u_]^n_.,x_Symbol] :=
  With[{lst=QuotientOfLinearsParts[u,x]},
  Int[Cosh[(lst[[1]]+lst[[2]]*x)/(lst[[3]]+lst[[4]]*x)]^n,x]] /;
IGtQ[n,0] && QuotientOfLinearsQ[u,x]

3.  ∫u ((Sinh[v])^p)((Hyper[w])^q)dx

1.  ∫u ((Sinh[v])^p)((Sinh[w])^q)dx

1:  ∫u ((Sinh[v])^p) ((Sinh[w])^q)dx  when  w==v

Derivation: Algebraic simplification

Rule: If  w==v, then

∫u ((Sinh[v])^p) ((Sinh[w])^q)dx  ⟶  ∫u ((Sinh[v])^(p+q))dx

Program code:

Int[u_.*Sinh[v_]^p_.*Sinh[w_]^q_.,x_Symbol] :=
  Int[u*Sinh[v]^(p+q),x] /;
EqQ[w,v]

Int[u_.*Cosh[v_]^p_.*Cosh[w_]^q_.,x_Symbol] :=
  Int[u*Cosh[v]^(p+q),x] /;
EqQ[w,v]

2:  ∫((Sinh[v])^p)((Sinh[w])^q)dx  when p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫((Sinh[v])^p)((Sinh[w])^q)dx  ⟶  ∫TrigReduce[((Sinh[v])^p)((Sinh[w])^q)]dx

Program code:

Int[Sinh[v_]^p_.*Sinh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[Sinh[v]^p*Sinh[w]^q,x],x] /;
IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

Int[Cosh[v_]^p_.*Cosh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[Cosh[v]^p*Cosh[w]^q,x],x] /;
IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

3:  ∫(x^m)((Sinh[v])^p)((Sinh[w])^q)dx  when m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫(x^m)((Sinh[v])^p)((Sinh[w])^q)dx  ⟶  ∫(x^m)TrigReduce[((Sinh[v])^p)((Sinh[w])^q)]dx

Program code:

Int[x_^m_.*Sinh[v_]^p_.*Sinh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[x^m,Sinh[v]^p*Sinh[w]^q,x],x] /;
IGtQ[m,0] && IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

Int[x_^m_.*Cosh[v_]^p_.*Cosh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[x^m,Cosh[v]^p*Cosh[w]^q,x],x] /;
IGtQ[m,0] && IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

2.  ∫u ((Sinh[v])^p)((Cosh[w])^q)dx

1:  ∫u ((Sinh[v])^p) ((Cosh[w])^p)dx  when  w==v ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: Sinh[z] Cosh[z]==(1/2) Sinh[2 z]

Rule: If  w==v ∧ p∈ℤ, then

∫u ((Sinh[v])^p) ((Cosh[w])^p)dx  ⟶  (1/(2^p))∫u ((Sinh[2v])^p)dx

Program code:

Int[u_.*Sinh[v_]^p_.*Cosh[w_]^p_.,x_Symbol] :=
  1/2^p*Int[u*Sinh[2*v]^p,x] /;
EqQ[w,v] && IntegerQ[p]

2:  ∫((Sinh[v])^p)((Cosh[w])^q)dx  when p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫((Sinh[v])^p)((Cosh[w])^q)dx  ⟶  ∫TrigReduce[((Sinh[v])^p)((Cosh[w])^q)]dx

Program code:

Int[Sinh[v_]^p_.*Cosh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[Sinh[v]^p*Cosh[w]^q,x],x] /;
IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

3:  ∫(x^m)((Sinh[v])^p)((Cosh[w])^q)dx  when m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If m∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫(x^m)((Sinh[v])^p)((Cosh[w])^q)dx  ⟶  ∫(x^m)TrigReduce[((Sinh[v])^p)((Cosh[w])^q)]dx

Program code:

Int[x_^m_.*Sinh[v_]^p_.*Cosh[w_]^q_.,x_Symbol] :=
  Int[ExpandTrigReduce[x^m,Sinh[v]^p*Cosh[w]^q,x],x] /;
IGtQ[m,0] && IGtQ[p,0] && IGtQ[q,0] && (PolynomialQ[v,x] && PolynomialQ[w,x] || BinomialQ[{v,w},x] && IndependentQ[Cancel[v/w],x])

3.  ∫u ((Sinh[v])^p)((Tanh[w])^q)dx

1:  ∫Sinh[v] ((Tanh[w])^n)dx  when  n>0 ∧ w≠v ∧ x∉v-w

Derivation: Algebraic expansion

Basis: Sinh[v] Tanh[w]==Cosh[v]-Cosh[v-w] Sech[w]

Basis: Cosh[v] Coth[w]==Sinh[v]+Cosh[v-w] Csch[w]

Rule: If  n>0 ∧ w≠v ∧ x∉v-w, then

∫Sinh[v] ((Tanh[w])^n)dx  ⟶  ∫Cosh[v] ((Tanh[w])^(n-1))dx-Cosh[v-w] ∫Sech[w] ((Tanh[w])^(n-1))dx

Program code:

Int[Sinh[v_]*Tanh[w_]^n_.,x_Symbol] :=
  Int[Cosh[v]*Tanh[w]^(n-1),x] - Cosh[v-w]*Int[Sech[w]*Tanh[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

Int[Cosh[v_]*Coth[w_]^n_.,x_Symbol] :=
  Int[Sinh[v]*Coth[w]^(n-1),x] + Cosh[v-w]*Int[Csch[w]*Coth[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

4.  ∫u ((Sinh[v])^p)((Coth[w])^q)dx

1:  ∫Sinh[v] ((Coth[w])^n)dx  when  n>0 ∧ w≠v ∧ x∉v-w

Derivation: Algebraic expansion

Basis: Sinh[v] Coth[w]==Cosh[v]+Sinh[v-w] Csch[w]

Basis: Cosh[v] Tanh[w]==Sinh[v]-Sinh[v-w] Sech[w]

Rule: If  n>0 ∧ w≠v ∧ x∉v-w, then

∫Sinh[v] ((Coth[w])^n)dx  ⟶  ∫Cosh[v] ((Coth[w])^(n-1))dx+Sinh[v-w] ∫Csch[w] ((Coth[w])^(n-1))dx

Program code:

Int[Sinh[v_]*Coth[w_]^n_.,x_Symbol] :=
  Int[Cosh[v]*Coth[w]^(n-1),x] + Sinh[v-w]*Int[Csch[w]*Coth[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

Int[Cosh[v_]*Tanh[w_]^n_.,x_Symbol] :=
  Int[Sinh[v]*Tanh[w]^(n-1),x] - Sinh[v-w]*Int[Sech[w]*Tanh[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

5.  ∫u ((Sinh[v])^p)((Sech[w])^q)dx

1:  ∫Sinh[v] ((Sech[w])^n)dx  when  n>0 ∧ w≠v ∧ x∉v-w

Derivation: Algebraic expansion

Basis: Sinh[v] Sech[w]==Cosh[v-w] Tanh[w]+Sinh[v-w]

Basis: Cosh[v]*Csch[w]==Cosh[v-w]*Coth[w]+Sinh[v-w]

Rule: If  n>0 ∧ w≠v ∧ x∉v-w, then

∫Sinh[v] ((Sech[w])^n)dx  ⟶  Cosh[v-w] ∫Tanh[w] ((Sech[w])^(n-1))dx+Sinh[v-w] ∫((Sech[w])^(n-1))dx

Program code:

Int[Sinh[v_]*Sech[w_]^n_.,x_Symbol] :=
  Cosh[v-w]*Int[Tanh[w]*Sech[w]^(n-1),x] + Sinh[v-w]*Int[Sech[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

Int[Cosh[v_]*Csch[w_]^n_.,x_Symbol] :=
  Cosh[v-w]*Int[Coth[w]*Csch[w]^(n-1),x] + Sinh[v-w]*Int[Csch[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

6.  ∫u ((Sinh[v])^p)((Csch[w])^q)dx

1:  ∫Sinh[v] ((Csch[w])^n)dx  when  n>0 ∧ w≠v ∧ x∉v-w

Derivation: Algebraic expansion

Basis: Sinh[v] Csch[w]==Sinh[v-w] Coth[w]+Cosh[v-w]

Basis: Cosh[v] Sech[w]==Sinh[v-w] Tanh[w]+Cosh[v-w]

Rule: If  n>0 ∧ w≠v ∧ x∉v-w, then

∫Sinh[v] ((Csch[w])^n)dx  ⟶  Sinh[v-w] ∫Coth[w] ((Csch[w])^(n-1))dx+Cosh[v-w] ∫((Csch[w])^(n-1))dx

Program code:

Int[Sinh[v_]*Csch[w_]^n_.,x_Symbol] :=
  Sinh[v-w]*Int[Coth[w]*Csch[w]^(n-1),x] + Cosh[v-w]*Int[Csch[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

Int[Cosh[v_]*Sech[w_]^n_.,x_Symbol] :=
  Sinh[v-w]*Int[Tanh[w]*Sech[w]^(n-1),x] + Cosh[v-w]*Int[Sech[w]^(n-1),x] /;
GtQ[n,0] && NeQ[w,v] && FreeQ[v-w,x]

4:  ∫(((e+f x))^m)(((a+b Sinh[c+d x] Cosh[c+d x]))^n)dx

Derivation: Algebraic simplification

Basis: Sinh[z] Cosh[z]==(1/2) Sinh[2 z]

Rule:

∫(((e+f x))^m)(((a+b Sinh[c+d x] Cosh[c+d x]))^n)dx  ⟶  ∫(((e+f x))^m)(((a+(1/2) b Sinh[2 c+2 d x]))^n)dx

Program code:

Int[(e_.+f_.*x_)^m_.*(a_+b_.*Sinh[c_.+d_.*x_]*Cosh[c_.+d_.*x_])^n_.,x_Symbol] :=
  Int[(e+f*x)^m*(a+b*Sinh[2*c+2*d*x]/2)^n,x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

5:  ∫(x^m)(((a+b ((Sinh[c+d x])^2)))^n)dx  when  a-b≠0 ∧ m∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: ((Sinh[z])^2)==(1/2) (-1+Cosh[2 z])

Basis: ((Cosh[z])^2)==(1/2) (1+Cosh[2 z])

Note: This rule should be replaced with rules that directly reduce the integrand rather than transforming it using hyperbolic power expansion!

Rule: If  a-b≠0 ∧ m∈(SuperPlus[ℤ])∧ n∈(SuperMinus[ℤ]), then

∫(x^m)(((a+b ((Sinh[c+d x])^2)))^n)dx  ⟶  (1/(2^n))∫(x^m)(((2 a-b+b Cosh[2 c+2 d x]))^n)dx

Program code:

Int[x_^m_.*(a_+b_.*Sinh[c_.+d_.*x_]^2)^n_,x_Symbol] :=
  1/2^n*Int[x^m*(2*a-b+b*Cosh[2*c+2*d*x])^n,x] /;
FreeQ[{a,b,c,d},x] && NeQ[a-b,0] && IGtQ[m,0] && ILtQ[n,0] && (EqQ[n,-1] || EqQ[m,1] && EqQ[n,-2])

Int[x_^m_.*(a_+b_.*Cosh[c_.+d_.*x_]^2)^n_,x_Symbol] :=
  1/2^n*Int[x^m*(2*a+b+b*Cosh[2*c+2*d*x])^n,x] /;
FreeQ[{a,b,c,d},x] && NeQ[a-b,0] && IGtQ[m,0] && ILtQ[n,0] && (EqQ[n,-1] || EqQ[m,1] && EqQ[n,-2])

6:  ∫((((f+g x))^m)/(a+b ((Cosh[d+e x])^2)+c ((Sinh[d+e x])^2)))dx  when  m∈(SuperPlus[ℤ])∧ a+b≠0 ∧ a+c≠0

Derivation: Algebraic simplification

Basis: a+b ((Cosh[z])^2)+c ((Sinh[z])^2)==(1/2) (2 a+b-c+(b+c) Cosh[2 z])

Rule: If  m∈(SuperPlus[ℤ])∧ a+b≠0 ∧ a+c≠0, then

∫((((f+g x))^m)/(a+b ((Cosh[d+e x])^2)+c ((Sinh[d+e x])^2)))dx  ⟶  2∫((((f+g x))^m)/(2 a+b-c+(b+c) Cosh[2 d+2 e x]))dx

Program code:

Int[(f_.+g_.*x_)^m_./(a_.+b_.*Cosh[d_.+e_.*x_]^2+c_.*Sinh[d_.+e_.*x_]^2),x_Symbol] :=
  2*Int[(f+g*x)^m/(2*a+b-c+(b+c)*Cosh[2*d+2*e*x]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[m,0] && NeQ[a+b,0] && NeQ[a+c,0]

Int[(f_.+g_.*x_)^m_.*Sech[d_.+e_.*x_]^2/(b_+c_.*Tanh[d_.+e_.*x_]^2),x_Symbol] :=
  2*Int[(f+g*x)^m/(b-c+(b+c)*Cosh[2*d+2*e*x]),x] /;
FreeQ[{b,c,d,e,f,g},x] && IGtQ[m,0]

Int[(f_.+g_.*x_)^m_.*Sech[d_.+e_.*x_]^2/(b_.+a_.*Sech[d_.+e_.*x_]^2+c_.*Tanh[d_.+e_.*x_]^2),x_Symbol] :=
  2*Int[(f+g*x)^m/(2*a+b-c+(b+c)*Cosh[2*d+2*e*x]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[m,0] && NeQ[a+b,0] && NeQ[a+c,0]

Int[(f_.+g_.*x_)^m_.*Csch[d_.+e_.*x_]^2/(c_+b_.*Coth[d_.+e_.*x_]^2),x_Symbol] :=
  2*Int[(f+g*x)^m/(b-c+(b+c)*Cosh[2*d+2*e*x]),x] /;
FreeQ[{b,c,d,e,f,g},x] && IGtQ[m,0]

Int[(f_.+g_.*x_)^m_.*Csch[d_.+e_.*x_]^2/(c_.+b_.*Coth[d_.+e_.*x_]^2+a_.*Csch[d_.+e_.*x_]^2),x_Symbol] :=
  2*Int[(f+g*x)^m/(2*a+b-c+(b+c)*Cosh[2*d+2*e*x]),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[m,0] && NeQ[a+b,0] && NeQ[a+c,0]

7:  ∫(((e+f x) (A+B Sinh[c+d x]))/(((a+b Sinh[c+d x]))^2))dx  when  a A+b B==0

Derivation: Integration by parts

Basis: If  a A+b B==0, then (( (A+B Sinh[c+d x]))/(((a+b Sinh[c+d x]))^2))==(∂_x)((B Cosh[c+d x])/(a d (a+b Sinh[c+d x])))

Rule: If  a A+b B==0, then

∫(((e+f x) (A+B Sinh[c+d x]))/(((a+b Sinh[c+d x]))^2))dx  ⟶  ((B (e+f x) Cosh[c+d x])/(a d (a+b Sinh[c+d x])))-((B f)/(a d))∫((Cosh[c+d x])/(a+b Sinh[c+d x]))dx

Program code:

Int[(e_.+f_.*x_)*(A_+B_.*Sinh[c_.+d_.*x_])/(a_+b_.*Sinh[c_.+d_.*x_])^2,x_Symbol] :=
  B*(e+f*x)*Cosh[c+d*x]/(a*d*(a+b*Sinh[c+d*x])) - 
  B*f/(a*d)*Int[Cosh[c+d*x]/(a+b*Sinh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && EqQ[a*A+b*B,0]

Int[(e_.+f_.*x_)*(A_+B_.*Cosh[c_.+d_.*x_])/(a_+b_.*Cosh[c_.+d_.*x_])^2,x_Symbol] :=
  B*(e+f*x)*Sinh[c+d*x]/(a*d*(a+b*Cosh[c+d*x])) -
  B*f/(a*d)*Int[Sinh[c+d*x]/(a+b*Cosh[c+d*x]),x] /;
FreeQ[{a,b,c,d,e,f,A,B},x] && EqQ[a*A-b*B,0]

8:  ∫(((e+f x))^m) ((Sinh[a+b (((c+d x))^n)])^p)dx  when  m∈(SuperPlus[ℤ])∧ p∈ℚ

Derivation: Integration by linear substitution

Rule: If  m∈(SuperPlus[ℤ])∧ p∈ℚ, then

∫(((e+f x))^m) ((Sinh[a+b (((c+d x))^n)])^p)dx  ⟶  (1/(d^(m+1)))Subst[∫(((d e-c f+f x))^m) ((Sinh[a+b (x^n)])^p)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*Sinh[a_.+b_.*(c_+d_.*x_)^n_]^p_.,x_Symbol] :=
  1/d^(m+1)*Subst[Int[(d*e-c*f+f*x)^m*Sinh[a+b*x^n]^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && RationalQ[p]

Int[(e_.+f_.*x_)^m_.*Cosh[a_.+b_.*(c_+d_.*x_)^n_]^p_.,x_Symbol] :=
  1/d^(m+1)*Subst[Int[(d*e-c*f+f*x)^m*Cosh[a+b*x^n]^p,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,n},x] && IGtQ[m,0] && RationalQ[p]

9:  ∫((Sech[v])^m) (((a+b Tanh[v]))^n)dx  when  ((m-1)/2)∈ℤ ∧ m+n==0

Derivation: Algebraic simplification

Basis: ((a+b Tanh[z])/(Sech[z]))==a Cosh[z]+b Sinh[z]

Rule: If  ((m-1)/2)∈ℤ ∧ m+n==0, then

∫((Sech[v])^m) (((a+b Tanh[v]))^n)dx  ⟶  ∫(((a Cosh[v]+b Sinh[v]))^n)dx

Program code:

Int[Sech[v_]^m_.*(a_+b_.*Tanh[v_])^n_.,x_Symbol] :=
  Int[(a*Cosh[v]+b*Sinh[v])^n,x] /;
FreeQ[{a,b},x] && IntegerQ[(m-1)/2] && EqQ[m+n,0]

Int[Csch[v_]^m_.*(a_+b_.*Coth[v_])^n_.,x_Symbol] :=
  Int[(b*Cosh[v]+a*Sinh[v])^n,x] /;
FreeQ[{a,b},x] && IntegerQ[(m-1)/2] && EqQ[m+n,0]

10:  ∫u ((Sinh[a+b x])^m)((Sinh[c+d x])^n)dx  when  m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  m∈(SuperPlus[ℤ])∧ n∈(SuperPlus[ℤ]), then

∫u ((Sinh[a+b x])^m)((Sinh[c+d x])^n)dx  ⟶  ∫u TrigReduce[((Sinh[a+b x])^m)((Sinh[c+d x])^n)]dx

Program code:

Int[u_.*Sinh[a_.+b_.*x_]^m_.*Sinh[c_.+d_.*x_]^n_.,x_Symbol] :=
  Int[ExpandTrigReduce[u,Sinh[a+b*x]^m*Sinh[c+d*x]^n,x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0] && IGtQ[n,0]

Int[u_.*Cosh[a_.+b_.*x_]^m_.*Cosh[c_.+d_.*x_]^n_.,x_Symbol] :=
  Int[ExpandTrigReduce[u,Cosh[a+b*x]^m*Cosh[c+d*x]^n,x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0] && IGtQ[n,0]

11:  ∫Sech[a+b x]Sech[c+d x]dx  when  (b^2)-(d^2)==0 ∧ b c-a d≠0

Derivation: Algebraic expansion

Basis: If  (b^2)-(d^2)==0 ∧ b c-a d≠0 , then Sech[a+b x] Sech[c+d x]==-Csch[((b c-a d)/d)]Tanh[a+b x]+Csch[((b c-a d)/b)]Tanh[c+d x]

Rule: If  (b^2)-(d^2)==0 ∧ b c-a d≠0 , then

∫Sech[a+b x] Sech[c+d x]dx  ⟶  -Csch[((b c-a d)/d)] ∫Tanh[a+b x]dx+Csch[((b c-a d)/b)] ∫Tanh[c+d x]dx

Program code:

Int[Sech[a_.+b_.*x_]*Sech[c_+d_.*x_],x_Symbol] :=
  -Csch[(b*c-a*d)/d]*Int[Tanh[a+b*x],x] + Csch[(b*c-a*d)/b]*Int[Tanh[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2-d^2,0] && NeQ[b*c-a*d,0]

Int[Csch[a_.+b_.*x_]*Csch[c_+d_.*x_],x_Symbol] :=
  Csch[(b*c-a*d)/b]*Int[Coth[a+b*x],x] - Csch[(b*c-a*d)/d]*Int[Coth[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2-d^2,0] && NeQ[b*c-a*d,0]

12:  ∫Tanh[a+b x] Tanh[c+d x]dx  when  (b^2)-(d^2)==0 ∧ b c-a d≠0

Derivation: Algebraic expansion

Basis: If  (b^2)-(d^2)==0, then Tanh[a+b x] Tanh[c+d x]==(b/d)-(b/d)Cosh[((b c-a d)/d)] Sech[a+b x] Sech[c+d x]

Rule: If  (b^2)-(d^2)==0 ∧ b c-a d≠0 , then

∫Tanh[a+b x] Tanh[c+d x]dx  ⟶  ((b x)/d)-(b/d)Cosh[((b c-a d)/d)] ∫Sech[a+b x]Sech[c+d x]dx

Program code:

Int[Tanh[a_.+b_.*x_]*Tanh[c_+d_.*x_],x_Symbol] :=
  b*x/d - b/d*Cosh[(b*c-a*d)/d]*Int[Sech[a+b*x]*Sech[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2-d^2,0] && NeQ[b*c-a*d,0]

Int[Coth[a_.+b_.*x_]*Coth[c_+d_.*x_],x_Symbol] :=
  b*x/d + Cosh[(b*c-a*d)/d]*Int[Csch[a+b*x]*Csch[c+d*x],x] /;
FreeQ[{a,b,c,d},x] && EqQ[b^2-d^2,0] && NeQ[b*c-a*d,0]

13:  ∫u(((a Cosh[v]+b Sinh[v]))^n)dx  when  (a^2)-(b^2)==0

Derivation: Algebraic simplification

Basis: If  (a^2)-(b^2)==0, then a Cosh[z]+b Sinh[z]==a (e^((a z)/b))

Rule: If  (a^2)-(b^2)==0, then

∫u(((a Cosh[v]+b Sinh[v]))^n)dx  ⟶  ∫u(((a (e^((a v)/b))))^n)dx

Program code:

Int[u_.*(a_.*Cosh[v_]+b_.*Sinh[v_])^n_.,x_Symbol] :=
  Int[u*(a*E^(a/b*v))^n,x] /;
FreeQ[{a,b,n},x] && EqQ[a^2-b^2,0]

14.  ∫u Sin[d (((a+b Log[c (x^n)]))^2)]dx

1:  ∫Sinh[d (((a+b Log[c (x^n)]))^2)]dx

Derivation: Algebraic expansion

Basis: Sinh[z]==-((e^(-z))/2)+((e^z)/2)

Rule:

∫Sinh[d (((a+b Log[c (x^n)]))^2)]dx  ⟶  (1/2) ∫(e^(-d (((a+b Log[c (x^n)]))^2)))dx+(1/2) ∫(e^(d (((a+b Log[c (x^n)]))^2)))dx

Program code:

Int[Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])^2],x_Symbol] :=
  -1/2*Int[E^(-d*(a+b*Log[c*x^n])^2),x] + 1/2*Int[E^(d*(a+b*Log[c*x^n])^2),x] /;
FreeQ[{a,b,c,d,n},x]

Int[Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])^2],x_Symbol] :=
  1/2*Int[E^(-d*(a+b*Log[c*x^n])^2),x] + 1/2*Int[E^(d*(a+b*Log[c*x^n])^2),x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫(((e x))^m) Sinh[d (((a+b Log[c (x^n)]))^2)]dx

Derivation: Algebraic expansion

Basis: Sinh[z]==-((e^(-z))/2)+((e^z)/2)

Rule:

∫(((e x))^m) Sinh[d (((a+b Log[c (x^n)]))^2)]dx  ⟶  (1/2) ∫(((e x))^m) (e^(-d (((a+b Log[c (x^n)]))^2)))dx+(1/2) ∫(((e x))^m) (e^(d (((a+b Log[c (x^n)]))^2)))dx

Program code:

Int[(e_.*x_)^m_.*Sinh[d_.*(a_.+b_.*Log[c_.*x_^n_.])^2],x_Symbol] :=
  -1/2*Int[(e*x)^m*E^(-d*(a+b*Log[c*x^n])^2),x] + 1/2*Int[(e*x)^m*E^(d*(a+b*Log[c*x^n])^2),x] /;
FreeQ[{a,b,c,d,e,m,n},x]

Int[(e_.*x_)^m_.*Cosh[d_.*(a_.+b_.*Log[c_.*x_^n_.])^2],x_Symbol] :=
  1/2*Int[(e*x)^m*E^(-d*(a+b*Log[c*x^n])^2),x] + 1/2*Int[(e*x)^m*E^(d*(a+b*Log[c*x^n])^2),x] /;
FreeQ[{a,b,c,d,e,m,n},x]